VoiceMeeter-interface/VB.ahk

SetWorkingDir, A_MyDocuments\D3K
#SingleInstance force
#MaxHotkeysPerInterval 99000000
#HotkeyInterval 99000000
#KeyHistory 0
#UseHook
#Persistent
ListLines Off
SendMode Input ; Recommended for new scripts due to its superior speed and reliability.
SetTitleMatchMode, RegEx
StringCaseSense Off 

OnExit("cleanup_before_exit")
SetFormat, Float, 0.3
global VMR_FUNCTIONS := {}
global VMR_DLL_DRIVE := "C:"
global VMR_DLL_DIRPATH := "Program Files (x86)\VB\Voicemeeter"
global VMR_DLL_FILENAME_32 := "VoicemeeterRemote.dll"
global VMR_DLL_FILENAME_64 := "VoicemeeterRemote64.dll"
global VMR_DLL_FULL_PATH := VMR_DLL_DRIVE . "\" . VMR_DLL_DIRPATH . "\"
Sleep, 500
if (A_Is64bitOS) {
	VMR_DLL_FULL_PATH .= VMR_DLL_FILENAME_64
} else {
	VMR_DLL_FULL_PATH .= VMR_DLL_FILENAME_32
}


; == START OF EXECUTION ==
; ========================

; Load the VoicemeeterRemote DLL:
; This returns a module handle
global VMR_MODULE := DllCall("LoadLibrary", "Str", VMR_DLL_FULL_PATH, "Ptr")
if (ErrorLevel || VMR_MODULE == 0)
	die("Attempt to load VoiceMeeter Remote DLL failed.")

; Populate VMR_FUNCTIONS
add_vmr_function("Login")
add_vmr_function("Logout")
add_vmr_function("RunVoicemeeter")
add_vmr_function("SetParameterFloat")
add_vmr_function("GetParameterFloat")
add_vmr_function("IsParametersDirty")

; "Login" to Voicemeeter, by calling the function in the DLL named 'VBVMR_Login()'...
login_result := DllCall(VMR_FUNCTIONS["Login"], "Int")
if (ErrorLevel || login_result < 0)
	die("VoiceMeeter Remote login failed.")

; If the login returns 1, that apparently means that Voicemeeter isn't running,
; so we start it; pass 1 to run Voicemeeter, or 2 for Voicemeeter Banana:
if (login_result == 1) {
	DllCall(VMR_FUNCTIONS["RunVoicemeeter"], "Int", 2, "Int")
	if (ErrorLevel)
	die("Attempt to run VoiceMeeter failed.")
	Sleep 2000
}

Switch A_Args[1]
{
Case "restart":
	adjustToggle("Command.Restart", "1")
	Reload		; It doesn't like processing MIDI after we send commands to VM ¯\_(ツ)_/¯ 
	Return
Case "show":
	adjustToggle("Command.Show", "1")
	Reload		; It doesn't like processing MIDI after we send commands to VM ¯\_(ツ)_/¯ 
	Return
}

; == MIDI ==
; ==========
#Include, MIDI\MidiStart.ahk
#Include, MIDI\Midi_In_and_GuiMonitor.ahk	; this file contains: the function to parse midi message into parts we can work with and a midi monitor.
#Include, MIDI\MidiRules.ahk			; this file contains: Rules for manipulating midi input then sending modified midi output.
#Include, MIDI\Midi_under_the_hood.ahk    ; this file contains: (DO NOT EDIT THIS FILE) all the dialogs to set up midi ports and midi message handling.


;	Cases explained so you don't have to go into the korg software:
;	Faders (Control Channel 1-8, left to right)	
;		0 = Fader
;		1 = Dial
;		2 =	S
;		3 = M
;		4 = R
;	Other buttons (Control Channel 10)
;		1 = Track <
;		2 =	Track >
;		3 = Cycle
;		4 = Marker Set
;		5 = Marker <
;		6 = Marker >
;		7 = <<
;		8 = >>
;		9 = Stop
;		10 = Play
;		11 = Record


midiCCin:
	cc := byte1		; The Control Channel
	val := byte2	; The value (0-127 for faders, 0 or 1 for buttons (that part is set with the software))
	nonmusic := "Netflix|YouTube|Corridor"	; Windows to control media in instead of music

	;	Definitions for the virtual faders
	WorkLapR	:= "Strip[0]."
	MicR		:= "Strip[1]."
	PhoneR		:= "Strip[2]."
	;empty		:= "Strip[3]."
	Music		:= "Strip[4]."

	Desktop		:= "Strip[5]."
	CommsR		:= "Strip[6]."
	AlissaR		:= "Strip[7]."
	
	MicS		:= "Bus[0]."
	Speakers	:= "Bus[1]."
	;empty		:= "Bus[2]."
	PhoneS		:= "Bus[3]."
	WorkLapS	:= "Bus[4]."
	CommsS		:= "Bus[5]."
	AlissaS		:= "Bus[6]."

	Switch chan
	{
		Case 1: ; The first fader: Work Laptop
			Switch cc
				{
				Case 0:
					Lvl := fader_to_fader(val)
					adjustVolLvl(WorkLapR "Gain", Lvl)
					adjustVolLvl(AlissaR "Gain", Lvl)
					Return
				Case 1:
					Lvl := fader_to_fader(val)
					adjustVolLvl(WorkLapS "Gain", Lvl)	; WL Send, hardly ever needs adjusted
					adjustVolLvl(AlissaS "Gain", Lvl)	; Audio sent to Alissa
					Return
				Case 2:
					adjustToggle(WorkLapR "Solo", val)
					adjustToggle(AlissaR "Solo", val)
					Return
				Case 3:
					adjustToggle(WorkLapS "Mute", val)	; WL Send mute, if I need to mute it I can just use the fader
					flag("WLsend", val)
					Return
				Case 4:
					adjustToggle(WorkLapR "A4", val)	; Sends audio to phone VBAN stream
					Return
				Default:
					Return
				}
		Case 2: ; The second fader: Phone
			Switch cc
				{
				Case 0:
					Lvl := fader_to_fader(val)
					adjustVolLvl(PhoneS "Gain", Lvl)
					Return
				Case 1:
					Lvl := fader_to_fader(val)
					adjustVolLvl(PhoneR "Gain", Lvl)
					Return
				Case 2:
					If (val)
					{
						adjustToggle("Command.Restart", val)
						Reload		; It doesn't like processing MIDI after we restart VM ¯\_(ツ)_/¯ 
					}
					Return
				Case 3:
					adjustToggle(PhoneS "Mute", val)
					adjustToggle(PhoneR "Mute", val)
					Return
				Default:
					Return
				}
		Case 3: ; The third fader: Desktop Audio
			Switch cc
				{
				Case 0:
					Lvl := fader_to_fader(val)
					adjustVolLvl(Desktop "Gain", Lvl)
					Return
				Case 1:
					Lvl := dial_to_pan(val)
					adjustVolLvl(Desktop "Pan_x", Lvl)
				Case 2:
					adjustToggle(Desktop "Solo", val)
					Return
				Case 3:
					adjustToggle(Desktop "Mute", val)
					Return
				Case 4:
					adjustToggle(Desktop "A4", val)
					Return
				Default:
					Return
				}
		Case 4: ; The fourth fader: Comms Receive
			Switch cc
				{
				Case 0:
					Lvl := fader_to_fader(val)
					adjustVolLvl(CommsR "Gain", Lvl)
					Return
				Case 1:
					Lvl := dial_to_pan(val)
					adjustVolLvl(CommsR "Pan_x", Lvl)
					; make Telegram go in the opposite direction
					Lvl := dial_to_rev_pan(val)
					adjustVolLvl(AlissaR "Pan_x", Lvl)
				Case 2:
					adjustToggle(CommsR "Solo", val)
					Return
				Case 3:
					adjustToggle(CommsR "Mute", val)
					Return
				Case 4:		; sends Comms recieve and Alissa to Phone
					adjustToggle(CommsR "A4", val)
					adjustToggle(AlissaR "A4", val)
					Return
				Default:
					Return
				}
		Case 5: ; The fifth fader: Comms Send
			Switch cc
				{
				Case 0:
					Lvl := fader_to_fader(val)
					adjustVolLvl(CommsS "Gain", Lvl)
					Return
				Case 2:	; Push to Talk/Mute
					if (readParam(CommsS "Mute"))
					{
						adjustToggle(CommsS "Mute", False)
						flag("Csend", False)
					} else {
						adjustToggle(CommsS "Mute", True)
						flag("Csend", True)
					}
					Return
				Case 3:
					adjustToggle(CommsS "Mute", val)
					flag("Csend",val)
					Return
				Case 4:	; Send music to Discord & Work
					adjustToggle(Music "B1", val)
					adjustToggle(Music "B2", val)
					adjustToggle(Music "A5", val)
					if (val)
					{
						Send {F22}	; Toggle PTT/Voice Activity (Shows up as UNK133 in discord)
						Send {F23 down}	; PTT button (Shows up as UNK134 in discord)
					} else {
						Send {F23 up}
						Send {F22}	; Toggle PTT/Voice Activity
					}
					Return
				Default:
					Return
				}
		Case 6: ; The sixth fader: Speakers
			Switch cc
				{
				Case 0:
					Lvl := fader_to_fader(val)
					adjustVolLvl(Speakers "Gain", Lvl)
					Return
				Case 1:
					Lvl := fader_to_fader(val)
					adjustVolLvl(AlissaR "Gain", Lvl)
				Case 3:
					adjustToggle(Speakers "Mute", val)
					Return
				Case 4:
					adjustToggle(AlissaR "Mute", val)
					adjustToggle(AlissaS "Mute", val)
					Return
				Default:
					Return
				}
		Case 7: ; The seventh fader: Mic
			Switch cc
				{
				Case 0:
					Lvl := fader_to_fader(val)
					adjustVolLvl(MicS "Gain", Lvl)
					Return
				Case 2:
					adjustToggle(MicR "Mute", val)
					Return
				Case 3:
					adjustToggle(MicR "Mute", val)
					adjustToggle(MicS "Mute", val)
					Return
				Case 4:
					adjustToggle(MicR "Mute", val)
					Return
				Default:
					Return
				}
		Case 8:	; The eighth fader: Music
			Switch cc
				{
				Case 0:
					Lvl := fader_to_fader(val)
					adjustVolLvl(Music "Gain", Lvl)
					Return
				Case 1:
					Lvl := dial_to_pan(val)
					adjustVolLvl(Music "Pan_x", Lvl)
				Case 2:
					adjustToggle(Music "Solo", val)
					Return
				Case 3:
					adjustToggle(Music "Mute", val)
					Return
				Case 4:
					adjustToggle(Music "A4", val)
					Return
				Default:
					Return
				}
		Case 10:	; Buttons on the left
			Switch cc
			{
				Case 1: ; Media Previous
					if (val)
					{
						If (WinActive(nonmusic,, "Music"))
						{
							Send, {j}	; Skip back
						} Else
						{
							Send, {Media_Prev}
						}
					}
					Return
				Case 2:	; Media Next
					if (val)
					{
						If (WinActive(nonmusic,, "Music"))
						{
							Send, {l}	; skip forward
						} Else
						{
							Send, {Media_Next}
						}
					}
					Return
				Case 3:	; Media Play/Pause
					If (WinActive(nonmusic,, "Music"))
					{
						Send, {Space}
					} Else
					{
						Send, {Media_Play_Pause}
					}
					Return
				Case 4:	; Set button
					if (val)
					{
						if (readParam(CommsS "Mute"))
						{
							adjustToggle(CommsS "Mute", False)
							remuteC := True
						}
						if (readParam(WorkLapS "Mute"))
						{
							adjustToggle(WorkLapS "Mute", False)
							remuteW := True
						}
						Send {F22}		; Toggle PTT/Voice Activity
						Send {F23 down}	; PTT
						adjustToggle("Recorder.Play", True)
					} else {
						if (remuteC)
						{
							adjustToggle(CommsS "Mute", True)
							remuteC := ""
						}
						if (remuteW)
						{
							adjustToggle(WorkLapS "Mute", True)
							remuteW := ""
						}
						Send {F23 up}	; PTT
						Send {F22}		; Toggle PTT/Voice Activity
						adjustToggle("Recorder.Stop", True)
						Sleep, 250
						adjustToggle("Recorder.Stop", True)
					}
					Return
				Case 5:	; <- under Marker / dislike song
					if !(val)
					{
						Send {F20}
					}
					Return
				Case 6:	; -> under Marker / like song
					if !(val)
					{
						Send {F21}
					}
					Return
				Case 7:	; Rewind
					if (val)
					{
						adjustToggle("Recorder.REW", True)
					} else {
						adjustToggle("Recorder.Play", True)
					}					
					Return
				Case 8:	; Fast Forward
					if (val)
					{
						adjustToggle("Recorder.FF", True)
					} else {
						adjustToggle("Recorder.Play", True)
					}					
					Return
				Case 9:
					adjustToggle("Recorder.Stop", val)
					Return
				Case 10:
					adjustToggle("Recorder.Play", val)
					Return
				Case 11:
					adjustToggle("Recorder.Record", val)
					Return				
				Default:
					Gosub, SendCC
					Return
			}
		Default:
			Gosub, SendCC
			Return
	}
Return


; == HOTKEYS ==
; =============
; (untested cause I don't use them)
Volume_Mute::
	b0M := readParam(Speakers "Mute")	; Speakers
	b1M := readParam(MicS "Mute")	; Headphones
	b2M := readParam(WorkLapS "Mute")	; Work Laptop Send
	b3M := readParam(PhoneS "Mute")	; Comms Send
	b4M := readParam(AlissaS "Mute")	; Recording
	cM := b0M + b1M + b2M + b3M + b4M
	
	if (cM = "5")
	{	; Unmute the ones that were unmuted before
		adjustToggle(Speakers "Mute", b0Ms)	; Speakers
		adjustToggle(MicS "Mute", b1Ms)	; Headphones
		adjustToggle(WorkLapS "Mute", b2Ms)	; Work Laptop Send
		adjustToggle(PhoneS "Mute", b3Ms)	; Comms Send
		adjustToggle(AlissaS "Mute", b4Ms)	; Recording
	} else {
		adjustToggle(Speakers "Mute", True)	; Speakers
		adjustToggle(MicS "Mute", True)	; Headphones
		adjustToggle(WorkLapS "Mute", True)	; Work Laptop Send
		adjustToggle(PhoneS "Mute", True)	; Comms Send
		adjustToggle(AlissaS "Mute", True)	; Recording
		b0Ms := b0M
		b1Ms := b1M
		b2Ms := b2M
		b3Ms := b3M
		b4Ms := b4M
		
	}
Return


; == Functions ==
; ===============

;	I need to redo this function...
flag(loc, val)
{
	Switch loc
	{
	Case "Csend":	;	Comms send
		If !(val)	;	Unmuted
		{
			If (readParam(WorkLapS "Mute"))	;	WLsend unmuted
			{
				data := "blink/red"
			} Else
			{
				data := "on/green"
			}
		} Else
		{
			data := "off"
		}
	Case "WLsend":	;	WL send
		If !(val)	;	Unmuted
		{
			If !(readParam(CommsS "Mute"))	;	Comms muted
			{
				data := "blink/red"
			} Else
			{
				data := "on/green"
			}
		} Else
		{
			data := "off"
		}
	Default:
		Return
	}
	Run %A_AhkPath% "flag.ahk" %data%
	Return
}

readParam(loc)
{
	Loop
	{
		pDirty := DLLCall(VMR_FUNCTIONS["IsParametersDirty"]) ;Check if parameters have changed. 
		if (pDirty==0) ;0 = no new paramters.
			break
		else if (pDirty<0) ;-1 = error, -2 = no server
			return ""
		else ;1 = New parameters -> update your display. (this only applies if YOU have a display, couldn't find any code to update VM display which can get off sometimes)
			if A_Index > 200
				return ""
			sleep, 20
	}
	tParamVal := 0.0
	NumPut(0.0, tParamVal, 0, "Float")
	statusLvl := DllCall(VMR_FUNCTIONS["GetParameterFloat"], "AStr", loc, "Ptr", &tParamVal, "Int")
	tParamVal := Round(NumGet(tParamVal, 0, "Float"))	; This wasn't originally rounded, which would return 1.000 instead of 1, which is just silly
	if (statusLvl < 0)
		return ""
	else
		return tParamVal
}

adjustVolLvl(loc, tVol)
{
	if (tVol > 12.0)
		tVol := 12.0
	else if (tVol < -60.0) 
		tVol := -60.0
	DllCall(VMR_FUNCTIONS["SetParameterFloat"], "AStr", loc, "Float", tVol, "Int")
	Return
}

adjustToggle(func, togg)
{
	DllCall(VMR_FUNCTIONS["SetParameterFloat"], "AStr", func, "Float", togg, "Int")
	; transition flag logic here?
	Return
}

adjustString(func, str)
{
	DllCall(VMR_FUNCTIONS["SetParameterFloat"], "AStr", func, "AStr", str, "Str")
	Return
}

fader_to_fader(val) ; Translates MIDI fader values to the VoiceMeeter software faders
{
	; The upper limit for faders in VM is 12.0
	; The lower limit for the faders in VM that I would like is -40.0, how low it should go when the physical fader is all the way at the bottom
	nval := Round(((val / 127) * 72) - 60)
	Return nval
}

; 	Formula: ((value / max value) * total range) - negative part of range
dial_to_pan(val)
{
	nval := Round((val / 127) - 0.5, 2)
	Return nval
}

dial_to_rev_pan(val)	; Pans in the opposite direction
{
	val := Round((val / 127) - 0.5, 2)
	val := -val
	Return val
}


add_vmr_function(func_name)
{
	VMR_FUNCTIONS[func_name] := DllCall("GetProcAddress", "Ptr", VMR_MODULE, "AStr", "VBVMR_" . func_name, "Ptr")
	if (ErrorLevel || VMR_FUNCTIONS[func_name] == 0)
		die("Failed to register VMR function " . func_name . ".")
}

cleanup_before_exit(exit_reason, exit_code)
{
	DllCall(VMR_FUNCTIONS["Logout"], "Int")
	; OnExit functions must return 0 to allow the app to exit.
	return 0
}

die(die_string:="UNSPECIFIED FATAL ERROR.", exit_status:=254)
{
	MsgBox 16, FATAL ERROR, %die_string%
	ExitApp exit_status
}